blob: afd0760f6df1a3767ee196c319e3af4ff80cd154 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
|
#
# Given a list of flags, add those which the C++ compiler supports to the target
#
include(CheckCXXCompilerFlag)
function(add_supported_cxx_flags target)
cmake_parse_arguments(ARG "PRIVATE;PUBLIC;INTERFACE" "" "" ${ARGN})
set(flags ${ARG_UNPARSED_ARGUMENTS})
if(ARG_PRIVATE)
set(private PRIVATE)
endif()
if(ARG_PUBLIC)
set(public PUBLIC)
endif()
if(ARG_INTERFACE)
set(interface INTERFACE)
endif()
foreach(flag ${flags})
# remove the `no-` prefix from warnings because gcc doesn't treat it as an
# error on its own
string(REGEX REPLACE "\\-Wno\\-(.+)" "-W\\1" flag_to_test "${flag}")
string(
REGEX REPLACE
"[^a-zA-Z0-9]+"
"_"
test_name
"CXXFLAG_${flag_to_test}"
)
check_cxx_compiler_flag("${flag_to_test}" ${test_name})
if(${test_name})
target_compile_options(
${target}
${private}
${public}
${interface}
${flag}
)
endif()
endforeach()
endfunction()
#
# Given a list of linker flags, add those which the compiler supports to the
# target
#
include(CheckLinkerFlag)
function(add_supported_cxx_linker_flags target)
cmake_parse_arguments(ARG "PRIVATE;PUBLIC;INTERFACE;BEFORE" "" "" ${ARGN})
set(flags ${ARG_UNPARSED_ARGUMENTS})
if(ARG_BEFORE)
set(before BEFORE)
endif()
if(ARG_PRIVATE)
set(private PRIVATE)
endif()
if(ARG_PUBLIC)
set(public PUBLIC)
endif()
if(ARG_INTERFACE)
set(interface INTERFACE)
endif()
foreach(flag ${flags})
string(
REGEX REPLACE
"[^a-zA-Z0-9]+"
"_"
test_name
"CXXLINKFLAG_${flag}"
)
check_linker_flag(CXX "${flag}" ${test_name})
if(${test_name})
target_link_options(
${target}
${before}
${private}
${public}
${interface}
${flag}
)
endif()
endforeach()
endfunction()
#
# Add our default compiler flags to a target
#
# Pass USE_EXTRA_WARNINGS to enable -WExtra or /W3
#
function(set_default_compile_options target)
cmake_parse_arguments(
ARG
"USE_EXTRA_WARNINGS;USE_FEWER_WARNINGS"
""
""
${ARGN}
)
set(warning_flags)
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
list(
APPEND
warning_flags
-Wall
# Disabled warnings:
-Wno-switch
-Wno-parentheses
-Wno-unused-local-typedefs
-Wno-class-memaccess
-Wno-assume
-Wno-reorder
-Wno-invalid-offsetof
-Wno-newline-eof
-Wno-return-std-move
# Allowed warnings:
# If a function returns an address/reference to a local, we want it to
# produce an error, because it probably means something very bad.
-Werror=return-local-addr
# Allow unused variables with a pattern of `if (auto v = as<...>(...))`.
# This pattern is very common in Slang code base.
-Wno-error=unused-but-set-variable
# Some warnings which are on by default in MSVC
-Wnarrowing
)
if(ARG_USE_EXTRA_WARNINGS)
list(APPEND warning_flags -Wextra)
endif()
if(ARG_USE_FEWER_WARNINGS)
list(
APPEND
warning_flags
-Wno-class-memaccess
-Wno-unused-variable
-Wno-unused-parameter
-Wno-sign-compare
-Wno-unused-function
-Wno-unused-value
-Wno-unused-but-set-variable
-Wno-implicit-fallthrough
-Wno-missing-field-initializers
-Wno-strict-aliasing
-Wno-maybe-uninitialized
)
endif()
elseif(CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
list(APPEND warning_flags)
if(ARG_USE_EXTRA_WARNINGS)
list(APPEND warning_flags /W4)
elseif(ARG_USE_FEWER_WARNINGS)
list(APPEND warning_flags /W0)
else()
list(APPEND warning_flags /W2)
endif()
endif()
add_supported_cxx_flags(${target} PRIVATE ${warning_flags})
if(NOT WIN32)
# these options are for ELF specific and not for Windows
add_supported_cxx_linker_flags(
${target}
PRIVATE
# Don't assume that symbols will be resolved at runtime
"-Wl,--no-undefined"
# No reason not to do this? Useful when using split debug info
"-Wl,--build-id"
)
endif()
set_target_properties(
${target}
PROPERTIES # -fvisibility=hidden
CXX_VISIBILITY_PRESET
hidden
C_VISIBILITY_PRESET
hidden
VISIBILITY_INLINES_HIDDEN
ON
# C++ standard
CXX_STANDARD
20
# pic
POSITION_INDEPENDENT_CODE
ON
)
target_compile_definitions(
${target}
PRIVATE # Add _DEBUG depending on the build configuration
$<$<CONFIG:Debug>:_DEBUG>
# For including windows.h in a way that minimized namespace
# pollution. Although we define these here, we still set them
# manually in any header files which may be included by another
# project
WIN32_LEAN_AND_MEAN
VC_EXTRALEAN
NOMINMAX
# Use multi-byte character set on Windows
UNICODE
_UNICODE
)
#
# Settings dependent on config options
#
target_compile_definitions(
${target}
PRIVATE
SLANG_ENABLE_DXIL_SUPPORT=$<BOOL:${SLANG_ENABLE_DXIL}>
$<$<BOOL:${SLANG_ENABLE_FULL_DEBUG_VALIDATION}>:SLANG_ENABLE_FULL_IR_VALIDATION>
$<$<BOOL:${SLANG_ENABLE_IR_BREAK_ALLOC}>:SLANG_ENABLE_IR_BREAK_ALLOC>
$<$<BOOL:${SLANG_ENABLE_DX_ON_VK}>:SLANG_CONFIG_DX_ON_VK>
$<$<STREQUAL:${SLANG_LIB_TYPE},STATIC>:STB_IMAGE_STATIC>
)
if(SLANG_ENABLE_ASAN)
add_supported_cxx_flags(
${target}
PRIVATE
/fsanitize=address
-fsanitize=address
)
add_supported_cxx_linker_flags(
${target}
BEFORE
PUBLIC
/INCREMENTAL:NO
-fsanitize=address
)
endif()
endfunction()
|
