Initial import of code.

1 files changed, 181 insertions, 0 deletions

diff --git a/tests/hlsl/dxsdk/BasicHLSLFX11/BasicHLSLFX11.fx b/tests/hlsl/dxsdk/BasicHLSLFX11/BasicHLSLFX11.fx
new file mode 100644
index 000000000..1ecc1930a
--- /dev/null
+++ b/tests/hlsl/dxsdk/BasicHLSLFX11/BasicHLSLFX11.fx
@@ -0,0 +1,181 @@
+//TEST_IGNORE_FILE:
+//--------------------------------------------------------------------------------------
+// File: BasicHLSL11.fx
+//
+// The effect file for the BasicHLSL sample.  
+// 
+// Copyright (c) Microsoft Corporation. All rights reserved.
+//--------------------------------------------------------------------------------------
+
+
+//--------------------------------------------------------------------------------------
+// Global variables
+//--------------------------------------------------------------------------------------
+float4 g_MaterialAmbientColor;      // Material's ambient color
+float4 g_MaterialDiffuseColor;      // Material's diffuse color
+int g_nNumLights;
+
+float3 g_LightDir[3];               // Light's direction in world space
+float4 g_LightDiffuse[3];           // Light's diffuse color
+float4 g_LightAmbient;              // Light's ambient color
+
+Texture2D g_MeshTexture;            // Color texture for mesh
+
+float    g_fTime;                   // App's time in seconds
+float4x4 g_mWorld;                  // World matrix for object
+float4x4 g_mWorldViewProjection;    // World * View * Projection matrix
+
+//--------------------------------------------------------------------------------------
+// DepthStates
+//--------------------------------------------------------------------------------------
+DepthStencilState EnableDepth
+{
+    DepthEnable = TRUE;
+    DepthWriteMask = ALL;
+    DepthFunc = LESS_EQUAL;
+};
+
+//--------------------------------------------------------------------------------------
+// Texture samplers
+//--------------------------------------------------------------------------------------
+SamplerState MeshTextureSampler
+{
+    Filter = MIN_MAG_MIP_LINEAR;
+    AddressU = Wrap;
+    AddressV = Wrap;
+};
+
+
+//--------------------------------------------------------------------------------------
+// Vertex shader output structure
+//--------------------------------------------------------------------------------------
+struct VS_OUTPUT
+{
+    float4 Position   : SV_POSITION; // vertex position 
+    float4 Diffuse    : COLOR0;      // vertex diffuse color (note that COLOR0 is clamped from 0..1)
+    float2 TextureUV  : TEXCOORD0;   // vertex texture coords 
+};
+
+
+//--------------------------------------------------------------------------------------
+// This shader computes standard transform and lighting
+//--------------------------------------------------------------------------------------
+VS_OUTPUT RenderSceneVS( float4 vPos : POSITION,
+                         float3 vNormal : NORMAL,
+                         float2 vTexCoord0 : TEXCOORD,
+                         uniform int nNumLights,
+                         uniform bool bTexture,
+                         uniform bool bAnimate )
+{
+    VS_OUTPUT Output;
+    float3 vNormalWorldSpace;
+  
+    float4 vAnimatedPos = vPos;
+    
+    // Animation the vertex based on time and the vertex's object space position
+    if( bAnimate )
+		vAnimatedPos += float4(vNormal, 0) * (sin(g_fTime+5.5)+0.5)*5;
+    
+    // Transform the position from object space to homogeneous projection space
+    Output.Position = mul(vAnimatedPos, g_mWorldViewProjection);
+    
+    // Transform the normal from object space to world space    
+    vNormalWorldSpace = normalize(mul(vNormal, (float3x3)g_mWorld)); // normal (world space)
+    
+    // Compute simple directional lighting equation
+    float3 vTotalLightDiffuse = float3(0,0,0);
+    for(int i=0; i<nNumLights; i++ )
+        vTotalLightDiffuse += g_LightDiffuse[i] * max(0,dot(vNormalWorldSpace, g_LightDir[i]));
+        
+    Output.Diffuse.rgb = g_MaterialDiffuseColor * vTotalLightDiffuse + 
+                         g_MaterialAmbientColor * g_LightAmbient;   
+    Output.Diffuse.a = 1.0f; 
+    
+    // Just copy the texture coordinate through
+    if( bTexture ) 
+        Output.TextureUV = vTexCoord0; 
+    else
+        Output.TextureUV = 0; 
+    
+    return Output;    
+}
+
+
+//--------------------------------------------------------------------------------------
+// Pixel shader output structure
+//--------------------------------------------------------------------------------------
+struct PS_OUTPUT
+{
+    float4 RGBColor : SV_Target;  // Pixel color
+};
+
+
+//--------------------------------------------------------------------------------------
+// This shader outputs the pixel's color by modulating the texture's
+//       color with diffuse material color
+//--------------------------------------------------------------------------------------
+PS_OUTPUT RenderScenePS( VS_OUTPUT In,
+                         uniform bool bTexture ) 
+{ 
+    PS_OUTPUT Output;
+
+    // Lookup mesh texture and modulate it with diffuse
+    if( bTexture )
+        Output.RGBColor = g_MeshTexture.Sample(MeshTextureSampler, In.TextureUV) * In.Diffuse;
+    else
+        Output.RGBColor = In.Diffuse;
+
+    return Output;
+}
+
+
+//--------------------------------------------------------------------------------------
+// Renders scene to render target using D3D11 Techniques
+//--------------------------------------------------------------------------------------
+technique11 RenderSceneWithTexture1Light
+{
+    pass P0
+    {
+        SetVertexShader( CompileShader( vs_4_0_level_9_1, RenderSceneVS( 1, true, true ) ) );
+        SetGeometryShader( NULL );
+        SetPixelShader( CompileShader( ps_4_0_level_9_1, RenderScenePS( true ) ) );
+
+        SetDepthStencilState( EnableDepth, 0 );
+    }
+}
+
+technique11 RenderSceneWithTexture2Light
+{
+    pass P0
+    {          
+        SetVertexShader( CompileShader( vs_4_0_level_9_1, RenderSceneVS( 2, true, true ) ) );
+        SetGeometryShader( NULL );
+        SetPixelShader( CompileShader( ps_4_0_level_9_1, RenderScenePS( true ) ) ); 
+        
+        SetDepthStencilState( EnableDepth, 0 );
+    }
+}
+
+technique11 RenderSceneWithTexture3Light
+{
+    pass P0
+    {          
+        SetVertexShader( CompileShader( vs_4_0_level_9_1, RenderSceneVS( 3, true, true ) ) );
+        SetGeometryShader( NULL );
+        SetPixelShader( CompileShader( ps_4_0_level_9_1, RenderScenePS( true ) ) );
+
+        SetDepthStencilState( EnableDepth, 0 );
+    }
+}
+
+technique11 RenderSceneNoTexture
+{
+    pass P0
+    {          
+        SetVertexShader( CompileShader( vs_4_0_level_9_1, RenderSceneVS( 1, true, true ) ) );
+        SetGeometryShader( NULL );
+        SetPixelShader( CompileShader( ps_4_0_level_9_1, RenderScenePS( false ) ) );
+
+        SetDepthStencilState( EnableDepth, 0 );
+    }
+}
\ No newline at end of file