Fix checking of interface conformances for nested types

Before this change, code like the following would crash the compiler:

```hlsl
interface IThing { /* ... */ }
struct Outer
{
    struct Inner : IThing
    {}
}
/* go on to use Outer.Inner */
```

The problem was that the front-end logic for checking interface conformances was *only* checking declarations at the top level of a module, or nested under a generic.
This change fixes the logic to recurse through the entire tree of declarations.
I have added a test case that uses a nested `struct` type to satisfy an associated type requirement, to confirm that the new check works as intended.

2 files changed, 65 insertions, 0 deletions

diff --git a/tests/compute/assoctype-nested.slang b/tests/compute/assoctype-nested.slang
new file mode 100644
index 000000000..b3d96306b
--- /dev/null
+++ b/tests/compute/assoctype-nested.slang
@@ -0,0 +1,61 @@
+// assoctype-nested.slang
+
+// Confirm that an associated type can be declared nested in its parent.
+
+//TEST(compute):COMPARE_COMPUTE_EX:-slang -compute
+//TEST(compute):COMPARE_COMPUTE_EX:-slang -compute -dx12
+//TEST(compute, vulkan):COMPARE_COMPUTE_EX:-vk -compute
+
+interface IRandomGenerator
+{
+	[mutating] int generateVal();
+}
+
+interface IRandomStrategy
+{
+	associatedtype Generator : IRandomGenerator;
+	Generator makeGenerator(int seed);
+}
+
+int helper<T:IRandomStrategy>(T strategy, int seed)
+{
+	var generator = strategy.makeGenerator(seed);
+	let val = generator.generateVal();
+	return val;
+}
+
+struct CounterStrategy : IRandomStrategy
+{
+	struct Generator : IRandomGenerator
+	{
+		int state;
+		[mutating] int generateVal()
+		{
+			return state++;
+		}
+	}
+
+	Generator makeGenerator(int seed)
+	{
+		Generator generator = { seed };
+		return generator;
+	}
+}
+
+int test(int val)
+{
+	CounterStrategy strategy;
+	return helper(strategy, val);
+}
+
+//TEST_INPUT:ubuffer(data=[0 0 0 0], stride=4):dxbinding(0),glbinding(0),out
+RWStructuredBuffer<int> gOutputBuffer;
+
+[numthreads(4, 1, 1)]
+void computeMain(uint3 dispatchThreadID : SV_DispatchThreadID)
+{
+	uint tid = dispatchThreadID.x;
+	int inputVal = tid;
+	int outputVal = test(inputVal);
+	gOutputBuffer[tid] = outputVal;
+}
\ No newline at end of file
diff --git a/tests/compute/assoctype-nested.slang.expected.txt b/tests/compute/assoctype-nested.slang.expected.txt
new file mode 100644
index 000000000..bc856dafa
--- /dev/null
+++ b/tests/compute/assoctype-nested.slang.expected.txt
@@ -0,0 +1,4 @@
+0
+1
+2
+3