WIP: CMake (#3326)

* More robust input and output selection in generator tools

* Add cmake build system

* Get slang-test running with cmake

* Bump lz4 and miniz dependencies

* Make cmake build more declarative

* Correct preprocessor logic in slang.h

* Add cuda test to compute/simple

* Remove empty cmake files

* output placement for cmake, and commenting

* Correct include paths in spirv-embed-generator

* Format cmake with gersemi

* Make cmake build clerer

* Neaten header generation

Also work around https://gitlab.kitware.com/cmake/cmake/-/issues/18399
by introducing correct_generated_properties to set the GENERATED flag in
the correct scope

* remove unused files

* use 3.20 to set GENERATOR property properly

* spelling

* more flexible linker arg setting

* replace slang-static with obj collection

* Set rpath and linker path correctly

* neaten generated file generation

* tests working with cmake build

* fix premake5 build

* comment and neaten cmake

* remove unnecessary dependency

* Build aftermath example only when aftermath is enabled

* Add slang-llvm and other dependencies

* Put modules alongside binaries

* Find slang-glslang correctly

* Better option handling

* comments

* add llvm build test

* Better option handling

* cmake wobble

* use UNICODE and _UNICODE

* remove other workflows

* use ccache

* neaten

* limit parallel for llvm build

* use ninja for build

* Windows and Darwin slang-llvm builds

* cache key

* verbose llvm build

* cl on windows

* sccache and cl.exe

* use cl.exe

* Correct package detection

* less verbosity

* Simplify miniz inclusion

* fix build with sccache

* Neaten llvm building

* neaten

* Neaten slang-llvm fetching

* more surgical workarounds

* Add ci action

* Get version from git

* better variable naming

* add missing include

* clean up after premake in cmake

* more docs on cmake build

* ci wobble

* add imgui target

* more selective source

* do not download swiftshader

* Some missing dependencies

* only build llvm on dispatch

* Disable /Zi in CI where sccache is present

* simplify

* set PIC for miniz

* set policies before project

* reengage workaround

* more runs on ci

* Add cmake presets

* Add cpack

* move iterator debug level to preset

* Correct lib flag

* simplify action

* Neaten cmake init

* Add todo

* Add simple test wrapper

* Add tests to workflow presets

* rename packing preset

* Correctly set definitions

* docs

* correct preset names

* Make slang-test depend on test-server/test-process

* neaten

* use workflow in actions

* install docs

* Correct module install dir

* debug dist workflow

* Install headers

* neaten header globbing

* Neaten dependency handling

* make lib and bin variables

* Do not set compiler for vs builds, unnecessary

* docs

* allow setting explicit source for target

* maintain archive subdir

* cmake docs

* install headers

* place targets into folders

* cmake docs

* nest external projects in folder

* remove name clash

* Neater external packages

* meta targets in folder structure

* cleaner slang-glslang dll

* Add missing static directive to slang-no-embedded-stdlib

* more robust module copying

* make slang-test the startup project

* folder tweak

* Make FETCH_BINARY the default on all platforms

* Set DEBUG_DIR

* add natvis files to source

* skip spirv tests

* remove test step from debug dist

* Add build to .gitignore

* redo warnings to be more like premake

* Update imgui

* clean more premake files

* Disable PCH for glslang, gcc throws a warning

* Add /MP for msvc builds

* warning wobble

* Add script to build llvm

* Add slang-llvm and generators components

* Build slang-llvm in ci

* comments

* fetch llvm with git

* better abi approximation for cache

* better sccache key

* formatting

* Correct logic around disabling problematic debug info for ccache

* exclude gcc and clang from windows ci

* Make dist workflows use system llvm

* naming

* restore normal dist builds

* formatting

* run tests in ci

* Correct slang-llvm url setting

* Rely on the system to find the test tool library

* actions matrix wiggle

* cope with OSX ancient bash

* Correct compilers on windows

* more ci debugging

* Correct rpath handling on OSX

* neaten

* correct path to slang-llvm

* Correct rpath separator on osx

* Find slang-llvm correctly

* smoke tests only on osx

* ci wobble

* Give MacOS module a dylib suffix

* get swiftshader correctly

* cope with bsd cp

* remove debug output

* full tests on osx

* ci wobble

* Add some vk tests to expected failures

* simplify ci

* ci wobble

* exclude dx12 tests from github ci

* remove cmake code for building llvm

* warnings

* warnings as errors for cl

* spirv-tools in path

* add aarch64 ci build

* Add SLANG_GENERATORS_PATH option for prebuilt generators

* neaten

* Correct generator target name

* remove yaml anchors because github actions does not support them

* Demote CMake in docs

Also add info on cross compiling

* Restore premake CI

* use minimal ci for cmake

* Write miniz_export for premake build

and .gitignore it

* Mention build config tool options in docs

* Remove redefined macro for miniz

* regenerate vs project

1 files changed, 78 insertions, 0 deletions

diff --git a/external/CMakeLists.txt b/external/CMakeLists.txt
new file mode 100644
index 000000000..e61db9921
--- /dev/null
+++ b/external/CMakeLists.txt
@@ -0,0 +1,78 @@
+# Don't let all these packages spam up with status messages, filter to only the
+# important stuff.
+# Don't change things however if the user has explicitly set
+# CMAKE_MESSAGE_LOG_LEVEL
+set(set_cmake_log_level FALSE)
+if(NOT CMAKE_MESSAGE_LOG_LEVEL)
+    set(set_cmake_log_level TRUE)
+    set(CMAKE_MESSAGE_LOG_LEVEL NOTICE)
+endif()
+
+# Miniz
+add_subdirectory(miniz EXCLUDE_FROM_ALL)
+set_property(TARGET miniz PROPERTY POSITION_INDEPENDENT_CODE ON)
+# Work around https://github.com/richgel999/miniz/pull/292
+get_target_property(miniz_c_launcher miniz C_COMPILER_LAUNCHER)
+if(MSVC AND miniz_c_launcher MATCHES "ccache")
+    set_property(TARGET miniz PROPERTY C_COMPILER_LAUNCHER)
+    set_property(TARGET miniz PROPERTY MSVC_DEBUG_INFORMATION_FORMAT "")
+endif()
+
+# LZ4
+set(LZ4_BUNDLED_MODE ON)
+add_subdirectory(lz4/build/cmake EXCLUDE_FROM_ALL)
+if(MSVC)
+    target_compile_options(
+        lz4_static
+        PRIVATE /wd5045 /wd4820 /wd4711 /wd6385 /wd6262
+    )
+endif()
+
+# Vulkan headers
+add_subdirectory(vulkan EXCLUDE_FROM_ALL)
+
+# SPIRV-Headers
+add_subdirectory(spirv-headers EXCLUDE_FROM_ALL)
+
+# SPIRV-Tools
+set(SPIRV_TOOLS_BUILD_STATIC ON)
+set(SPIRV_WERROR OFF)
+set(SPIRV_HEADER_DIR "${CMAKE_CURRENT_LIST_DIR}/spirv-headers/")
+set(SPIRV_SKIP_TESTS ON)
+add_subdirectory(spirv-tools EXCLUDE_FROM_ALL)
+
+# glslang
+set(SKIP_GLSLANG_INSTALL ON)
+set(ENABLE_OPT ON)
+set(ENABLE_PCH OFF)
+add_subdirectory(glslang EXCLUDE_FROM_ALL)
+
+# imgui
+add_library(imgui INTERFACE)
+target_include_directories(imgui INTERFACE "${CMAKE_CURRENT_LIST_DIR}/imgui")
+
+# Tidy things up:
+
+# Restore log level if we set it
+if(set_cmake_log_level)
+    unset(CMAKE_MESSAGE_LOG_LEVEL)
+endif()
+
+# for this directory and all subdirectories, prepend
+# `external/` to the IDE FOLDER property to every target
+function(make_external dir)
+    get_property(external_targets DIRECTORY ${dir} PROPERTY BUILDSYSTEM_TARGETS)
+    foreach(external_target ${external_targets})
+        get_property(folder TARGET ${external_target} PROPERTY FOLDER)
+        set_property(
+            TARGET ${external_target}
+            PROPERTY FOLDER "external/${folder}"
+        )
+    endforeach()
+
+    get_property(subdirs DIRECTORY ${dir} PROPERTY SUBDIRECTORIES)
+    foreach(subdir ${subdirs})
+        make_external(${subdir})
+    endforeach()
+endfunction()
+make_external(.)