From 2f44d9e01234911dd563f0456b9d861fd8db286d Mon Sep 17 00:00:00 2001
From: Yong He <yonghe@outlook.com>
Date: Mon, 18 Oct 2021 12:19:45 -0700
Subject: GFX: implement mutable shader objects. (#1963)

* GFX: implement mutable shader objects.

* Revert unnecessary changes

* Revert more changes.

* Fix clang errors.

* Fix clang/gcc errors.

* Fix clang errors.

* Remove CPU test.

* Fix after merge.

* Fix after merge.

* Remove gl test

* Code review fixes.

* Fixing all vk validation errors.

* Flush test output more often.

* Fix a crash in `specializeDynamicAssociatedTypeLookup`.

* temporarily disable std-lib-serialize test to see what happens

* Fix crashes.

* Make sure cpu gfx unit tests are properly disabled on TeamCity.

* Disable cpu test.

* Fix.

* Fix cuda.

* Disable nv-ray-tracing-motion-blur

Co-authored-by: Yong He <yhe@nvidia.com>
---
 tools/gfx-unit-test/mutable-shader-object.slang | 68 +++++++++++++++++++++++++
 1 file changed, 68 insertions(+)
 create mode 100644 tools/gfx-unit-test/mutable-shader-object.slang

(limited to 'tools/gfx-unit-test/mutable-shader-object.slang')

diff --git a/tools/gfx-unit-test/mutable-shader-object.slang b/tools/gfx-unit-test/mutable-shader-object.slang
new file mode 100644
index 000000000..42d520f13
--- /dev/null
+++ b/tools/gfx-unit-test/mutable-shader-object.slang
@@ -0,0 +1,68 @@
+// mutable-shader-object.slang
+
+// This is a copy of `shader-object.slang` in `shader-object` example
+// for use by mutable-shader-object gfx unit test.
+
+// This file implements a simple compute shader that transforms
+// input floating point numbers stored in a `RWStructuredBuffer`.
+// Specifically, for each number x from input buffer, compute
+// f(x) and store the result back in the same buffer.
+
+// The compute shader supports multiple transformation functions,
+// such add(x, c) which returns x+c, or mul(x, c) which returns x*c.
+// This functions are implemented as types that conforms to the
+// `ITransformer` interface.
+
+// The main entry point function takes a parameter of `ITransformer`
+// type, and applies the transformation to numbers in the input
+// buffer. By defining the shader parameter using interfaces,
+// we enable the flexiblity to generate either specialized compute
+// kernels that performs specific transformation or a general
+// kernel that can perform any transformations encoded by the
+// parameter at run-time, without changing any shader code or
+// host-application logic for setting and preparing shader parameters.
+
+// Defines the transformer interface, which implements a single
+// `transform` operation.
+interface ITransformer
+{
+    float transform(float x);
+}
+
+// Represents a transform function f(x) = x + c.
+struct AddTransformer : ITransformer
+{
+    float c;
+    float transform(float x) { return x + c; }
+};
+
+// Represents a transform function f(x) = x * c.
+struct MulTransformer : ITransformer
+{
+    float c;
+    float transform(float x) { return x * c; }
+};
+
+// Represents a composite function f(x) = f0(f1(x));
+struct CompositeTransformer : ITransformer
+{
+    ITransformer func0;
+    ITransformer func1;
+    float transform(float x)
+    {
+        return func0.transform(func1.transform(x));
+    }
+};
+
+// Main entry-point. Applies the transformation encoded by `transformer`
+// to all elements in `buffer`.
+[shader("compute")]
+[numthreads(4,1,1)]
+void computeMain(
+    uint3 sv_dispatchThreadID : SV_DispatchThreadID,
+    uniform RWStructuredBuffer<float> buffer,
+    uniform ITransformer transformer)
+{
+    var input = buffer[sv_dispatchThreadID.x];
+    buffer[sv_dispatchThreadID.x] = transformer.transform(input);
+}
-- 
cgit v1.2.3