From bedc3421c9e1e0837fa69e30396a27a60f0fee53 Mon Sep 17 00:00:00 2001
From: Yong He <yonghe@outlook.com>
Date: Thu, 16 Oct 2025 11:23:13 -0700
Subject: Fix use of variadic generics with [Differentiable]. (#8736)

There was a bug that causes the compiler failing to treat a `no_diff
TypePack` as a type pack, and thus diagnose an error when resolving the
following call.

The fix is to unwrap any ModifiedType wrappers in `IsTypePack()` check.
---
 .../generics/variadic-generic-differentiable.slang | 59 ++++++++++++++++++++++
 .../generics/variadic-user-guide.slang             | 33 ++++++++++++
 2 files changed, 92 insertions(+)
 create mode 100644 tests/language-feature/generics/variadic-generic-differentiable.slang
 create mode 100644 tests/language-feature/generics/variadic-user-guide.slang

(limited to 'tests')

diff --git a/tests/language-feature/generics/variadic-generic-differentiable.slang b/tests/language-feature/generics/variadic-generic-differentiable.slang
new file mode 100644
index 000000000..55af3424c
--- /dev/null
+++ b/tests/language-feature/generics/variadic-generic-differentiable.slang
@@ -0,0 +1,59 @@
+//TEST:INTERPRET(filecheck=CHECK):
+
+// Test that we can call variadic generic [Differentiable] methods.
+
+interface IParameterExtractor
+{
+    [Differentiable]
+    void extract(no_diff uint x);
+}
+
+struct FloatParameterExtractor : IParameterExtractor
+{
+    [Differentiable]
+    void extract(no_diff uint x)
+    {
+        printf("fff\n");
+    }
+}
+
+[Differentiable]
+void extract_parameters_helper<T : IParameterExtractor>(
+    no_diff uint x,
+    T arg,
+    )
+{
+    arg.extract(x);
+}
+
+[Differentiable]
+void wrapper1<each T>(
+    uint x,
+    expand each T args, // compiler will add no_diff modifier here.
+    )
+    where T : IParameterExtractor
+{
+    expand extract_parameters_helper(x, each args);
+}
+
+[Differentiable]
+void wrapper2<each T>(
+    uint x,
+    expand each T args, // compiler will add no_diff modifier here.
+    )
+    where T : IParameterExtractor
+{
+    wrapper1(x, args);
+}
+
+
+void main()
+{
+    // There was a bug that causes the compiler failing to treat a `no_diff TypePack` as
+    // a type pack, and thus diagnose an error when resolving the following call.
+    //
+    wrapper2(1, FloatParameterExtractor(), FloatParameterExtractor());
+}
+
+// CHECK: fff
+// CHECK: fff
\ No newline at end of file
diff --git a/tests/language-feature/generics/variadic-user-guide.slang b/tests/language-feature/generics/variadic-user-guide.slang
new file mode 100644
index 000000000..1d1cfd790
--- /dev/null
+++ b/tests/language-feature/generics/variadic-user-guide.slang
@@ -0,0 +1,33 @@
+//TEST:INTERPRET(filecheck=CHECK):
+
+void printNumbers<each T>(expand each T args) where T == int
+{
+    // An single expression statement whose type will be `(void, void, ...)`.
+    // where each `void` is the result of evaluating expression `printf(...)` with
+    // each corresponding element in `args` passed as print operand.
+    //
+    expand printf("%d\n", each args);
+
+    // The above statement is equivalent to:
+    // ```
+    // (printf("%d\n", args[0]), printf("%d\n", args[1]), ..., printf("%d\n", args[n-1]));
+    // ```
+}
+void compute<each T>(expand each T args) where T == int
+{
+    // Maps every element in `args` to `elementValue + 1`, and forwards the
+    // new values as arguments to `printNumber`.
+    printNumbers(expand ((each args) + 1));
+
+    // The above statement is equivalent to:
+    // ```
+    // printNumber(args[0] + 1, args[1] + 1, ..., args[n-1] + 1);
+    // ```
+}
+void main()
+{
+    compute(1,2,3);
+    // CHECK: 2
+    // CHECK: 3
+    // CHECK: 4
+}
\ No newline at end of file
-- 
cgit v1.2.3